Tartalom

# ÖSSZESÍT függvény

Ez a függvény a tartománybeli számítások összesített eredményét adja vissza. Az alább felsorolt függvényeket használhatja. Az ÖSSZESÍT függvény lehetővé teszi rejtett sorok, hibák, a RÉSZÖSSZEG és más ÖSSZESÍT függvényeredmények kihagyását a számításból.

Az ÖSSZESÍT függvény függőleges adattartományokra alkalmazható, bekapcsolt automatikus szűrő mellett. Ha az automatikus szűrő nincs bekapcsolva, a függvény eredményének automatikus újraszámolása nem működik újonnan elrejtett sorokra. Vízszintes tartományok esetén nem várható el a működése, noha bizonyos korlátozásokkal azokra is alkalmazható. Ez azt jelenti, hogy az ÖSSZESÍT függvény nem ismeri fel a rejtett sorokat, noha helyesen kihagyja a hibákat, és a sorban lévő RÉSZÖSSZEG és más ÖSSZESÍT függvények eredményeit.

### Szintaxis

AGGREGATE(Function; Option; Number 1[; Number 2][; ... ;[Number 253]])

vagy

ÖSSZESÍT (függvény; beállítás; tömb[; k])

függvény - kötelező argumentum. Egy függvényindex vagy 1 és 19 közti értéket tartalmazó cellára való hivatkozás a következő táblázatnak megfelelően.

Függvényindex | Alkalmazott függvény
--- | ---
1 | ÁTLAG
2 | DARAB
3 | DARAB2
4 | MAX
5 | MIN
6 | SZORZAT
7 | SZÓR.M
8 | SZÓR.S
9 | SZUM
10 | VAR.M
11 | VAR.S
12 | MEDIÁN
13 | MÓDUSZ.EGY
14 | NAGY
15 | KICSI
16 | PERCENTILIS.TARTALMAZ
17 | KVARTILIS.TARTALMAZ
18 | PERCENTILIS.KIZÁR
19 | KVARTILIS.KIZÁR

beállítás - kötelező argumentum. Beállításindex, vagy egy 0 és 7 közti értéket tartalmazó cellára hivatkozás, ami meghatározza. hogy a függvény mit hagyjon figyelmen kívül a tartományban.

Beállításindex | Alkalmazott beállítás
--- | ---
0 | Csak a beágyazott RÉSZÖSSZEG és ÖSSZESÍT függvények figyelmen kívül hagyása
1 | Csak a rejtett sorok és a beágyazott RÉSZÖSSZEG és ÖSSZESÍT függvények figyelmen kívül hagyása
2 | Csak a hibák és a beágyazott RÉSZÖSSZEG és ÖSSZESÍT függvények figyelmen kívül hagyása
3 | A rejtett sorok, hibák és a beágyazott RÉSZÖSSZEG és ÖSSZESÍT függvények figyelmen kívül hagyása
4 | Semmit ne hagyjon figyelmen kívül
5 | Csak a rejtett sorok figyelmen kívül hagyása
6 | Csak a hibák figyelmen kívül hagyása
7 | Csak a rejtett sorok és a hibák figyelmen kívül hagyása

Number1 – required argument. The first numeric argument (if the range is set by a list of values inside the function) or a reference to a cell that contains it.

Number2, 3, ... – optional. A numeric argument or a reference to a cell (up to 253 arguments), for which you need the aggregate value.

Array – required argument. The array can be specified by the boundaries of the range, the name of the named range or the column label.

Az oszlopcímkék használatához az „Oszlop- és sorcímkék automatikus megkeresése” funkciót engedélyezni kell.

k – required argument for the following functions: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. It is a numeric argument, which must correspond to the second argument of these functions.

### Példák

| A | B | C
1 | Első oszlop | Második oszlop | Harmadik oszlop
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #ZÉRÓOSZTÓ! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #ÉRTÉK! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Returns maximum value for the range A2:A9 = 34.

=ÖSSZESÍT(9;5;A5:C5)
Visszaadja az A5:C5 tartomány összegét (= 29), még ha az oszlopok egy része el is van rejtve.

=ÖSSZESÍT(9;5;B2:B9)
Visszaadja a B oszlop összegét (=115). Ha bármely sor el van rejtve, a függvény kihagyja annak értékét. Ha például a 7. sor el van rejtve, a függvény a 95 értéket adja vissza.

Ha a függvényt egy 3D tartományra kell alkalmaznia, ez a példa bemutatja a módját.

=ÖSSZESÍT(13;3;Munkalap1.B2:B9:Munkalap3.B2:B9)
A függvény visszaadja a második oszlopok értékeinek móduszát (=8) az 1-3. munkalapokon (amelyek azonos adatokat tartalmaznak).

Használhat cella- vagy tartományhivatkozást a képlet minden argumentumához. A következő példa bemutatja, ez hogyan működik. Emellett bemutatja, hogyan használhat oszlopcímkéket egy tömb megadására.

=ÖSSZESÍT(E3;E5;'Első oszlop')
Ha E5 = 13 és E5 = 5, akkor a függvény az első oszlop móduszát adja vissza (=10).

#### Technikai információk

Ez a funkció a LibreOffice 4.4 óta érhető el.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.AGGREGATE

Kapcsolódó témakörök

AGGREGATE wiki page.

ÁTLAG, DARAB, DARAB2, MAX, MIN, SZORZAT, SZÓR.M, SZÓR.S, SZUM, VAR.M, VAR.S, MEDIÁN, MÓDUSZ.EGY, NAGY, KICSI, PERCENTILIS.TARTALMAZ, KVARTILIS.TARTALMAZ, PERCENTILIS.KIZÁR, KVARTILIS.KIZÁR

Oszlop- és sorcímkék automatikus megkeresése